larssonmartin1998/.dotfiles
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions

feature: Add automated colorscheme switching to Ghostty, refactor

Browse source 
watchman_tmux into generic utility function.
This commit is contained in:
Martin Larsson 2025-07-25 11:44:53 +02:00
parent 6521dedbaa
commit a15f2238aa
7 changed files with 164 additions and 68 deletions
Download patch file Download diff file Expand all files Collapse all files

39
nix/home/common/watchman_colorsync_services.nix Normal file
View file

@ -0,0 +1,39 @@
{
pkgs,
lib,
config,
isLinux,
isDarwin,
...
}:
let
utils = import ../../utils.nix;
in
lib.mkMerge [
(utils.mkWatchmanTrigger {
inherit
pkgs
lib
config
isLinux
isDarwin
;
name = "ghostty";
triggerName = "ghostty_theme";
scriptPath = "$HOME/.config/ghostty/ghostty-change-theme.sh";
description = "Register watchman trigger for Ghostty themes.";
})
(utils.mkWatchmanTrigger {
inherit
pkgs
lib
config
isLinux
isDarwin
;
name = "tmux";
triggerName = "tmux_statusbar_color";
scriptPath = "$HOME/.config/tmux/tmux-statusbar-color.sh";
description = "Register watchman trigger for Tmux statusbar colors.";
})
]

66
nix/home/common/watchman_tmux.nix
View file

@ -1,66 +0,0 @@
{
pkgs,
lib,
config,
isLinux,
isDarwin,
...
}:
let
scriptPkg = pkgs.writeShellScriptBin "tmux-watchman-statuscolor" ''
set -euo pipefail
ROOT="$HOME/.local/state/colorsync"
TRIGGER_NAME="tmux_statusbar_color"
SCRIPT="$HOME/.config/tmux/tmux-statusbar-color.sh"
WATCHMAN="${pkgs.watchman}/bin/watchman"
"$WATCHMAN" -- watch-project "$ROOT" >/dev/null
"$WATCHMAN" -- trigger-del "$ROOT" "$TRIGGER_NAME" >/dev/null 2>&1 || true
"$WATCHMAN" -- trigger "$ROOT" "$TRIGGER_NAME" current -- bash "$SCRIPT"
'';
pathForService = lib.makeBinPath [
pkgs.watchman
pkgs.bash
pkgs.coreutils
];
linuxAttrs = lib.optionalAttrs isLinux {
systemd.user.startServices = "sd-switch";
systemd.user.services.tmux-watchman = {
Unit = {
Description = "Register watchman trigger for tmux statusbar color";
After = [ "graphical-session.target" ];
};
Service = {
Type = "oneshot";
ExecStart = "${scriptPkg}/bin/tmux-watchman-statuscolor";
Environment = [ "PATH=${pathForService}" ];
StandardOutput = "journal";
StandardError = "journal";
};
Install = {
WantedBy = [ "default.target" ];
};
};
};
darwinAttrs = lib.optionalAttrs isDarwin {
launchd.agents.tmux-watchman = {
enable = true;
config = {
ProgramArguments = [ "${scriptPkg}/bin/tmux-watchman-statuscolor" ];
RunAtLoad = true;
KeepAlive = false;
EnvironmentVariables = {
PATH = pathForService;
};
StandardOutPath = "${config.home.homeDirectory}/Library/Logs/tmux-watchman.log";
StandardErrorPath = "${config.home.homeDirectory}/Library/Logs/tmux-watchman.err";
};
};
};
in
linuxAttrs // darwinAttrs

2
nix/home/default.nix
View file

@ -67,7 +67,7 @@ let
in
{
imports = [
./common/watchman_tmux.nix
./common/watchman_colorsync_services.nix
./common/firefox.nix
];

82
nix/utils.nix
View file

@ -46,4 +46,86 @@ rec {
${pkgs.mkalias}/bin/mkalias "$src" "${outputDir}/$app_name"
done
'';
mkWatchmanTrigger =
{
pkgs,
lib,
config,
isLinux,
isDarwin,
name,
triggerName,
scriptPath,
root ? "$HOME/.local/state/colorsync",
description ? "Register watchman trigger for ${name}.",
watchExpr ? "current",
}:
let
serviceName = "${name}-watchman";
# e.g. tmux-watchman-statuscolor, ghostty-watchman-theme
binName =
let
trig = lib.replaceStrings [ "_" ] [ "-" ] triggerName;
in
"${serviceName}-${trig}";
scriptPkg = pkgs.writeShellScriptBin binName ''
set -euo pipefail
ROOT="${root}"
TRIGGER_NAME="${triggerName}"
SCRIPT="${scriptPath}"
WATCHMAN="${pkgs.watchman}/bin/watchman"
"$WATCHMAN" -- watch-project "$ROOT" >/dev/null
"$WATCHMAN" -- trigger-del "$ROOT" "$TRIGGER_NAME" >/dev/null 2>&1 || true
"$WATCHMAN" -- trigger "$ROOT" "$TRIGGER_NAME" ${watchExpr} -- bash "$SCRIPT"
'';
pathForService = lib.makeBinPath [
pkgs.watchman
pkgs.bash
pkgs.coreutils
];
linuxAttrs = lib.optionalAttrs isLinux {
systemd.user.startServices = "sd-switch";
systemd.user.services."${serviceName}" = {
Unit = {
Description = description;
After = [ "graphical-session.target" ];
};
Service = {
Type = "oneshot";
ExecStart = "${scriptPkg}/bin/${binName}";
Environment = [ "PATH=${pathForService}" ];
StandardOutput = "journal";
StandardError = "journal";
};
Install = {
WantedBy = [ "default.target" ];
};
};
};
darwinAttrs = lib.optionalAttrs isDarwin {
launchd.agents."${serviceName}" = {
enable = true;
config = {
ProgramArguments = [ "${scriptPkg}/bin/${binName}" ];
RunAtLoad = true;
KeepAlive = false;
EnvironmentVariables = {
PATH = pathForService;
};
StandardOutPath = "${config.home.homeDirectory}/Library/Logs/${serviceName}.log";
StandardErrorPath = "${config.home.homeDirectory}/Library/Logs/${serviceName}.err";
};
};
};
in
linuxAttrs // darwinAttrs;
}