Rename firefox -> librewolf, remove themeing which wasnt working anyway and fix sway keybinding for opening librewolf

2025-10-11 10:43:58 +02:00 · 2025-10-11 10:43:58 +02:00 · 6c4632d386
commit 6c4632d386
parent 18880ce370
3 changed files with 2 additions and 11 deletions
--- a/nix/home/common/librewolf.nix
+++ b/nix/home/common/librewolf.nix
@ -0,0 +1,124 @@
+{
+  pkgs,
+  nur,
+  ...
+}:
+let
+  bookmarks_data = [
+    [
+      "Search NixOS"
+      "https://search.nixos.org/"
+    ]
+    [
+      "Github Atlas Engine"
+      "https://www.github.com/LarssonMartin1998/atlas.git"
+    ]
+    [
+      "neovim/nvim-lspconfig"
+      "https://github.com/neovim/nvim-lspconfig/tree/master/lsp"
+    ]
+    [
+      "YouTube"
+      "https://www.youtube.com/"
+    ]
+    [
+      "ChatGPT"
+      "https://www.chatgpt.com/"
+    ]
+  ];
+
+  extensions = with nur.repos.rycee.firefox-addons; [
+    ublock-origin
+    bitwarden
+    vimium
+    privacy-badger
+    clearurls
+    stylus
+    react-devtools
+  ];
+in
+{
+  home.sessionVariables = {
+    MOZ_ENABLE_WAYLAND = "1";
+    MOZ_USE_XINPUT2 = "1";
+  };
+
+  programs.librewolf = {
+    enable = true;
+
+    policies = {
+      "DisableFirefoxStudies" = true;
+      "DisableTelemetry" = true;
+      "NoDefaultBookmarks" = false; # Without this, adding bookmarks declaratively doesnt work.
+    };
+
+    profiles.default = {
+      isDefault = true;
+      name = "DefaultProfile";
+
+      bookmarks = {
+        force = true;
+        settings = map (entry: {
+          name = builtins.elemAt entry 0;
+          url = builtins.elemAt entry 1;
+        }) bookmarks_data;
+      };
+
+      extensions = {
+        packages = extensions;
+      };
+
+      settings = {
+        "browser.startup.homepage" = "https://search.nixos.org";
+        "browser.shell.checkDefaultBrowser" = false;
+        "privacy.resistFingerprinting" = false;
+        "dom.security.https_only_mode" = true;
+        "browser.tabs.warnOnClose" = false;
+        "extensions.pocket.enabled" = false;
+        "browser.search.defaultenginename" = "ddg";
+        "gfx.webrender.all" = true;
+        "toolkit.legacyUserProfileCustomizations.stylesheets" = true;
+        "browser.tabs.allow_transparent_browser" = true;
+        "layout.css.prefers-color-scheme.content-override" = 2;
+      };
+
+      search = {
+        force = true;
+        default = "ddg";
+        order = [
+          "ddg"
+          "google"
+        ];
+        engines = {
+          "ddg".metaData = {
+            alias = "@d";
+            hidden = false;
+          };
+          "google".metaData = {
+            alias = "@g";
+            hidden = false;
+          };
+          "Nix Packages" = {
+            urls = [
+              {
+                template = "https://search.nixos.org/packages";
+                params = [
+                  {
+                    name = "type";
+                    value = "packages";
+                  }
+                  {
+                    name = "query";
+                    value = "{searchTerms}";
+                  }
+                ];
+              }
+            ];
+            icon = "${pkgs.nixos-icons}/share/icons/hicolor/scalable/apps/nix-snowflake.svg";
+            definedAliases = [ "@np" ];
+          };
+        };
+      };
+    };
+  };
+}