Merge branch 'main' of github.com:LarssonMartin1998/.dotfiles

nix/home/common/firefox.nix

@@ -0,0 +1,96 @@
+{
+  pkgs,
+  nur,
+  ...
+}:
+{
+  programs = {
+    firefox = {
+      enable = true;
+      package = pkgs.firefox-wayland;
+
+      policies = {
+        "DisableFirefoxStudies" = true;
+        "DisableTelemetry" = true;
+      };
+
+      profiles = {
+        default = {
+          isDefault = true;
+          name = "DefaultProfile";
+          userChrome = ''
+            @import "theme/nordic-theme.css";
+            @import "theme/hide-single-tab.css";
+            @import "theme/matching-autocomplete-width.css";
+            @import "theme/system-icons.css";
+            @import "theme/symbolic-tab-icons.css";
+
+            @import "customChrome.css";
+          '';
+
+          extensions = {
+            packages = with nur.repos.rycee.firefox-addons; [
+              ublock-origin
+              bitwarden
+              vimium
+              privacy-badger
+              clearurls
+              darkreader
+            ];
+          };
+
+          settings = {
+            "browser.startup.homepage" = "https://search.nixos.org";
+            "browser.shell.checkDefaultBrowser" = false;
+            "privacy.resistFingerprinting" = false;
+            "dom.security.https_only_mode" = true;
+            "browser.tabs.warnOnClose" = false;
+            "extensions.pocket.enabled" = false;
+            "browser.search.defaultenginename" = "ddg";
+            "gfx.webrender.all" = true;
+            "toolkit.legacyUserProfileCustomizations.stylesheets" = true;
+            "browser.tabs.allow_transparent_browser" = true;
+          };
+
+          search = {
+            force = true;
+            default = "ddg";
+            order = [
+              "ddg"
+              "google"
+            ];
+            engines = {
+              "ddg".metaData = {
+                alias = "@d";
+                hidden = false;
+              };
+              "google".metaData = {
+                alias = "@g";
+                hidden = false;
+              };
+              "Nix Packages" = {
+                urls = [
+                  {
+                    template = "https://search.nixos.org/packages";
+                    params = [
+                      {
+                        name = "type";
+                        value = "packages";
+                      }
+                      {
+                        name = "query";
+                        value = "{searchTerms}";
+                      }
+                    ];
+                  }
+                ];
+                icon = "${pkgs.nixos-icons}/share/icons/hicolor/scalable/apps/nix-snowflake.svg";
+                definedAliases = [ "@np" ];
+              };
+            };
+          };
+        };
+      };
+    };
+  };
+}

nix/home/common/spotify_arm.nix

@@ -0,0 +1,80 @@
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}:
+let
+  # User-specific librespot settings
+  librespot_device_name = "asahi-nixos-librespot";
+  librespot_username = "martymeister98";
+  librespot_bitrate = "320";
+
+  # Construct librespot arguments
+  librespot_args = ''
+    --name ${librespot_device_name}
+    --username ${librespot_username}
+    --bitrate ${librespot_bitrate}
+    --disable-audio-cache
+    --initial-volume 50
+  '';
+
+  spotify_qt_initial_config = {
+    General = {
+      check_for_updates = false;
+      close_to_tray = false;
+      fallback_icons = false;
+      native_window = false;
+      notify_track_change = false;
+      relative_added = true;
+      show_changelog = false;
+      style = "Fusion";
+      style_palette = 2;
+      track_list_resize_mode = 0;
+      track_numbers = 1;
+      tray_album_art = false;
+      tray_icon = false;
+      tray_light_icon = false;
+    };
+    Qt = {
+      album_shape = 1;
+      album_size = 1;
+      library_layout = 1;
+      mirror_title_bar = false;
+      system_title_bar = true;
+      toolbar_position = 1;
+    };
+    Spotify = {
+      path = "${pkgs.librespot}/bin/librespot";
+      client_arguments = librespot_args;
+      always_start = true;
+      bitrate = 320;
+      disable_discovery = true;
+      start_client = true;
+    };
+  };
+
+  spotify_qt_initial_json = builtins.toJSON spotify_qt_initial_config;
+in
+{
+  home = {
+    packages = with pkgs; [
+      librespot
+      spotify-qt
+    ];
+
+    activation.conditionally_create_spotify-qt_config = lib.hm.dag.entryAfter [ "linkGeneration" ] ''
+      configFile="${config.home.homeDirectory}/.config/kraxarn/spotify-qt.json"
+      configDir="$(dirname "$configFile")"
+      if [ ! -f "$configFile" ]; then
+        echo "Initial spotify-qt.json not found. Creating with declarative defaults."
+
+        mkdir -p "$configDir"
+        printf '%s' '${spotify_qt_initial_json}' > "$configFile"
+        echo "Initial spotify-qt.json created at $configFile."
+      else
+        echo "spotify-qt.json already exists at $configFile. Skipping initial creation."
+      fi
+    '';
+  };
+}

nix/home/common/theming.nix

@@ -0,0 +1,119 @@
+{
+  pkgs,
+  ...
+}:
+
+let
+  cursor_name = "Banana-Blue";
+  cursor_base_size = 32;
+
+  bananaCursorBlueTarball = pkgs.fetchurl {
+    url = "https://github.com/ful1e5/banana-cursor/releases/download/v2.0.0/Banana-Blue.tar.xz";
+    sha256 = "sha256-mpTrvgYiMfamMebtytY0bLouSbaP3qEqP8pgCFl+xPQ=";
+  };
+
+  banana_cursor_blue = pkgs.stdenv.mkDerivation {
+    pname = "banana-cursor-blue";
+    version = "2.0.0";
+    src = bananaCursorBlueTarball;
+    nativeBuildInputs = [ pkgs.xz ];
+
+    dontBuild = true;
+
+    installPhase = ''
+      runHook preInstall
+      # Define shell variable using Nix interpolation for $out and the outer Nix var cursorName
+      local themeInstallDir="$out/share/icons/${cursor_name}"
+      mkdir -p "$themeInstallDir"
+      # Use the outer Nix var cursorName and the builder's $version shell variable
+      echo "Unpacking and installing pre-built theme ${cursor_name} (v$version) to $themeInstallDir"
+
+      if tar -xJf $src --strip-components=1 -C "$themeInstallDir"; then
+        echo "Unpacked successfully with --strip-components=1."
+      else
+        echo "-----------------------------------------------------"
+        echo "WARNING: Unpacking with --strip-components=1 failed (archive might not have a single top-level dir)."
+        echo "Listing archive contents:"
+        tar -tf $src || echo "Failed to list archive contents."
+        echo "Attempting unpack without --strip-components=1..."
+        rm -rf "$themeInstallDir"; mkdir -p "$themeInstallDir" # Clean and recreate before retry
+        if tar -xJf $src -C "$themeInstallDir"; then
+           echo "Unpacked successfully without --strip-components=1."
+        else
+           echo "ERROR: Failed to unpack archive even without --strip-components=1."
+           exit 1
+        fi
+        echo "-----------------------------------------------------"
+      fi
+      runHook postInstall
+    '';
+
+    meta = with pkgs.lib; {
+      description = "Banana Cursor Theme (Pre-built Blue variant v2.0.0)";
+      homepage = "https://github.com/ful1e5/banana-cursor";
+      license = licenses.gpl3Only;
+      maintainers = with maintainers; [ eelco ];
+      platforms = platforms.linux;
+    };
+  };
+
+  cursor_package = banana_cursor_blue;
+
+  effective_cursor_size_str = toString cursor_base_size;
+in
+{
+  wayland.windowManager.sway = {
+    config = {
+      seat = {
+        "*" = {
+          # Sway uses this for its own cursor and for XWayland applications.
+          # It takes the theme name and base size. Sway should scale this based on output settings.
+          xcursor_theme = "${cursor_name} ${effective_cursor_size_str}";
+        };
+      };
+    };
+  };
+
+  # Home Manager Pointer Configuration
+  # This makes the theme available and sets X11/GTK defaults via Home Manager mechanisms.
+  home = {
+    pointerCursor = {
+      name = cursor_name;
+      size = cursor_base_size;
+      package = cursor_package;
+      x11.enable = true;
+      gtk.enable = true;
+      x11.defaultCursor = "left_ptr";
+    };
+    packages = with pkgs; [
+      (cursor_package)
+    ];
+  };
+
+  qt = {
+    enable = true;
+    platformTheme.name = "gtk";
+    style.name = "Nordic";
+  };
+
+  gtk = {
+    enable = true;
+    cursorTheme = {
+      name = cursor_name;
+      size = cursor_base_size; # GTK applications will use this base size.
+      package = cursor_package;
+    };
+    theme = {
+      package = pkgs.nordic;
+      name = "Nordic";
+    };
+  };
+
+  xresources.properties = {
+    "Xcursor.theme" = cursor_name;
+  };
+
+  home.sessionVariables = {
+    XCURSOR_THEME = cursor_name;
+  };
+}

nix/home/darwin.nix

@@ -0,0 +1,13 @@
+{ pkgs, config, ... }:
+{
+  home = {
+    packages = with pkgs; [
+      gawk
+      discord
+    ];
+    file = {
+      ".config/aerospace/aerospace.toml".source =
+        config.lib.file.mkOutOfStoreSymlink ../../aerospace/aerospace.toml;
+    };
+  };
+}

nix/home/darwin_personal.nix

@@ -0,0 +1,9 @@
+{ pkgs, ... }:
+{
+  home = {
+    packages = with pkgs; [
+      clang
+      clang-tools
+    ];
+  };
+}

nix/home/darwin_work.nix

@@ -0,0 +1,14 @@
+{ pkgs, ... }:
+{
+  home = {
+    packages = with pkgs; [
+      (python311.withPackages (pythonPkgs: [
+        pythonPkgs.pip
+        pythonPkgs.setuptools
+      ]))
+      pcre
+      ccache
+      mkdocs
+    ];
+  };
+}

nix/home/default.nix

@@ -0,0 +1,122 @@
+{
+  pkgs,
+  config,
+  lib,
+  neovim-flake,
+  ...
+}:
+let
+  utils = import ../utils.nix;
+  dotfiles = [
+    [
+      ".zshrc"
+      "zsh/.zshrc"
+    ]
+    [
+      ".config/nvim"
+      "nvim"
+    ]
+    [
+      ".config/yazi"
+      "yazi"
+    ]
+    [
+      ".config/starship.toml"
+      "starship/starship.toml"
+    ]
+    [
+      ".tmux.conf"
+      "tmux/.tmux.conf"
+    ]
+    [
+      ".config/tmux"
+      "tmux"
+    ]
+    [
+      ".config/bat"
+      "bat"
+    ]
+    [
+      ".config/ghostty"
+      "ghostty"
+    ]
+    [
+      ".config/confutils"
+      "confutils"
+    ]
+    [
+      ".config/wallpapers"
+      "wallpapers"
+    ]
+  ];
+
+  codelldb = pkgs.runCommand "codelldb" { } ''
+    mkdir -p $out/bin
+    cp ${pkgs.vscode-extensions.vadimcn.vscode-lldb}/share/vscode/extensions/vadimcn.vscode-lldb/adapter/codelldb $out/bin/codelldb
+    chmod +x $out/bin/codelldb
+  '';
+in
+{
+  programs = {
+    zsh = {
+      enable = true;
+    };
+  };
+
+  home = {
+    stateVersion = "24.05";
+    packages = with pkgs; [
+      neovim-flake.packages.${system}.neovim
+      fzf
+      bat
+      git
+      yazi
+      tmux
+      eza
+      curl
+      wget
+      ripgrep
+      fd
+      jq
+      starship
+      fastfetch
+      nixfmt-rfc-style
+      luajit
+      zoxide
+      dart
+      go
+      rustup
+      zig
+      zls
+      nil
+      gopls
+      delve
+      golangci-lint
+      cmake
+      cmake-language-server
+      cmake-format
+      cmake-lint
+      python313Packages.debugpy
+      pyright
+      lua-language-server
+      gnumake
+      ninja
+      tldr
+      nerd-fonts.caskaydia-mono
+      lldb
+      nodejs
+      tree-sitter
+      codelldb
+      bottom
+      bc
+      cmatrix
+      svelte-language-server
+      bitwarden-cli
+    ];
+
+    file = utils.mk_symlinks { inherit config dotfiles; };
+    activation.batCache = lib.hm.dag.entryAfter [ "writeBoundary" ] ''
+      run ${pkgs.bat}/bin/bat cache --build
+    '';
+  };
+}

nix/home/linux.nix

@@ -0,0 +1,56 @@
+{
+  pkgs,
+  config,
+  ...
+}:
+
+let
+  utils = import ../utils.nix;
+  dotfiles = [
+    [
+      ".config/sway"
+      "sway"
+    ]
+    [
+      ".config/wofi"
+      "wofi"
+    ]
+  ];
+
+  pythonEnv = pkgs.python3.withPackages (
+    ps: with ps; [
+      i3ipc
+    ]
+  );
+in
+{
+  imports = [
+    ./common/theming.nix
+    ./common/firefox.nix
+  ];
+
+  home = {
+    packages = with pkgs; [
+      pythonEnv
+      wl-clipboard-rs
+      clang
+      clang-tools
+      gimp3
+      ghostty
+      mullvad
+      thunderbird
+      wofi
+      grim
+      slurp
+      pavucontrol
+      blueman
+      playerctl
+      mako
+    ];
+
+    file = utils.mk_symlinks { inherit config dotfiles; };
+  };
+  services = {
+    mako.enable = true;
+  };
+}

nix/home/linux_aarch.nix

@@ -0,0 +1,15 @@
+{
+  pkgs,
+  ...
+}:
+{
+  imports = [
+    ./common/spotify_arm.nix
+  ];
+
+  home = {
+    packages = with pkgs; [
+      legcord
+    ];
+  };
+}

nix/home/linux_x86.nix

@@ -0,0 +1,18 @@
+{
+  pkgs,
+  ...
+}:
+let
+  discord_wrapped = pkgs.writeShellScriptBin "discord" ''
+    #!${pkgs.runtimeShell}
+    exec "${pkgs.discord}/bin/discord" "$@" >/dev/null 2>&1
+  '';
+in
+{
+  home = {
+    packages = with pkgs; [
+      discord_wrapped
+      spotify
+    ];
+  };
+}

nix/home/local.nix

@@ -0,0 +1,12 @@
+{ ... }:
+{
+  # local_home.nix
+  # This is a template file that is committed to git with minimal changes.
+  # In order to use this and remain pure, each machine needs to create a local branch, i.e `machine-wsl` and set these variables
+  # accordingly, and then commit it.
+  home = {
+    # Stub values for demonstration. Override these in local branch.
+    username = "martin.larsson";
+    homeDirectory = "/Users/martin.larsson";
+  };
+}

nix/home/wsl.nix

@@ -0,0 +1,10 @@
+{ pkgs, ... }:
+{
+  home = {
+    packages = with pkgs; [
+      wslu
+      clang
+      clang-tools
+    ];
+  };
+}